ファイル更新日付をVBSで変更する。過去でも未来でも変更可

ファイルの更新日付を過去に戻してログローテーションテストしないと！

ってときによく使ってるけど毎回このソースをWebで探してますが、はてなブログなのでブログを削除されたらと思い自分用としてメモしました。

ファイル更新日付をVBSで変更する、の使い方

ソースを保存したらそのファイルにドラッグするだけ。

ソースは次の通り。

ファイル更新日付をVBSで変更する

▼filedate.vbsとかで保存してください。

 

If WScript.Arguments.Length = 0 Then
    sMsg = "更新日時を変更したいファイルをドラッグし、このアイコンにドロップしてください"
    MsgBox sMsg, vbOKOnly + vbInformation, "使い方"
Else
    sFile = WScript.Arguments.Item(0)
    Set oFS = CreateObject("Scripting.FileSystemObject")
    If oFS.FileExists(sFile) Then
        Set oFile = oFS.GetFile(sFile)
        sPath = oFile.ParentFolder & "\"
        sFileName = oFile.Name
        sCurrentDateTime = oFile.DateLastModified
        sNewDateTime = InputBox("更新日時をいつに変更しますか？", sFileName, sCurrentDateTime)
        If Len(sNewDateTime) > 0 Then
            If IsDate(sNewDateTime) Then
                sMsg = sFileName & " の更新日時を変更します" & vbCrLf & vbCrLf
                sMsg = sMsg & " 変更前: " & sCurrentDateTime & vbCrLf
                sMsg = sMsg & " 変更後: " & sNewDateTime & vbCrLf & vbCrLf
                sMsg = sMsg & "よろしいですか？"
                If MsgBox(sMsg, vbYesNo + vbQuestion, "確認") = vbYes Then
                    Set oShell = CreateObject("Shell.Application")
                    Set oFolder = oShell.Namespace(sPath)
                    Set oFolderItem = oFolder.ParseName(sFileName)
                    oFolderItem.ModifyDate = sNewDateTime
                End If
            Else
                MsgBox "不正な日付です", vbOKOnly + vbInformation, "エラー"
            End If
        End If
    Else
       MsgBox "これはファイルではありません", vbOKOnly + vbInformation, "エラー"
    End If
End If

 

参考：deck-no-bowブログ

著作権について

deck-no-bow様に帰属します。

当サイトでは備忘録として引用符にて転載させていただいております。